文字揃えを設定してリッチテキストに文字列を追加する

Sub subCreateRichText()
	Dim session   As New NotesSession
	Dim db        As     NotesDatabase
	Dim doc       As     NotesDocument
	Dim ritem     As     NotesRichTextItem
	Dim rpara1    As     NotesRichTextParagraphStyle
	
	'新規文書の作成
	Set db    = session.CurrentDatabase
	Set doc   = db.CreateDocument
	
	'文書情報の生成
	Call doc.ReplaceItemValue( "Form", "fmRichText" )
	Call doc.ReplaceItemValue( "Subject", "自動作成文書_" & Format( Now, "yyyymmddhhnnss" ) )
	
	'リッチテキスト段落属性の生成
	Set rpara1 = session.CreateRichTextParagraphStyle()
	
	'リッチテキストの生成
	Set ritem = New NotesRichTextItem( doc, "Body" )
	
	'右寄せで文字列を追加する
	rpara1.Alignment = ALIGN_RIGHT
	Call ritem.AppendParagraphStyle( rpara1 )
	Call ritem.AppendText( "1行目:この行は右寄せで作成しています。" )
	
	'中央寄せで文字列を追加する
	rpara1.Alignment = ALIGN_CENTER
	Call ritem.AppendParagraphStyle( rpara1 )
	Call ritem.AppendText( "2行目:この行は中央寄せで作成しています。" )
	
	'左寄せで文字列を追加する
	rpara1.Alignment = ALIGN_LEFT
	Call ritem.AppendParagraphStyle( rpara1 )
	Call ritem.AppendText( "3行目:この行は左寄せで作成しています。" )
	Call ritem.AddNewLine( 1 )
	
	'作成した文書の保存
	Call doc.Save( True, True, True )
End Sub





新規に文書を作成して、リッチテキストフィールド(Body)に文字揃えを設定した状態で文字列をセットする

LotusScript
guylocke
September 6, 2016 4:14 PM
Rating
0





No comments yetLogin first to comment...